Contrôler n'importe quel appareil avec votre télécommande TV via Arduino IR – Tutoriel Étape par Étape

Introduction

Dans ce tutoriel Arduino IR, nous allons apprendre à contrôler des dispositifs électroniques en utilisant une télécommande TV et un Arduino. Nous ferons quelques exemples allant du contrôle d'une simple LED, au contrôle de la vitesse d'un ventilateur DC, jusqu'au contrôle d'appareils électroménagers haute tension. Vous pouvez regarder la vidéo suivante ou lire le tutoriel écrit ci-dessous.

Comment ça fonctionne

Nous pouvons remarquer que la LED devant la télécommande TV clignote quand on appuie sur un bouton. En fait, nous ne pouvons voir cela qu'à travers une caméra car c'est une lumière infrarouge et elle n'est pas visible à l'œil nu.

Donc le clignotement signifie que quand on appuie sur un bouton, la LED infrarouge envoie une rafale de lumière ou des impulsions que nous devons recevoir avec un récepteur infrarouge.

Dans ce tutoriel, nous utiliserons le récepteur IR V 34838 qui a le diagramme de blocs suivant où nous pouvons voir qu'il va amplifier, filtrer et démoduler le signal reçu et fournir une sortie logique propre acceptable pour l'entrée numérique de la carte Arduino.

Ensuite, en utilisant la bibliothèque Arduino-IRremote de Ken Shirriff et son exemple de démonstration, nous pouvons voir sur le moniteur série un code hexadécimal unique pour chaque pression de bouton que nous pourrons utiliser lors de la création de notre programme.

Lien vers la bibliothèque Arduino-IRremote de Ken Shirriff : https://github.com/z3t0/Arduino-IRremote

Contrôler une LED RVB avec une télécommande TV

---

Vous pouvez obtenir les composants sur les sites ci-dessous :

• Récepteur IR
• LED RVB
• 3x résistances 220 Ohms
• Carte Arduino
• Plaque d'essai et fils de connexion

Nous allons contrôler la couleur de la LED en utilisant les 4 boutons colorés de la télécommande TV. Cela signifie que d'abord nous devons voir les codes hexadécimaux pour chacun de ces boutons en téléversant l'exemple IRrecvDemo et en exécutant le moniteur série. Nous appuierons sur chacun de ces boutons et noterons leurs codes.

Maintenant, nous allons modifier le code de démonstration comme ceci et ajouter des instructions if qui seront exécutées si un bouton particulier est pressé. Donc pour chaque bouton, nous définirons des valeurs RVB appropriées, et la fonction setColor() allumera la LED dans la couleur particulière. Pour plus de détails sur le fonctionnement d'une LED RVB avec Arduino, vous pouvez consulter mon tutoriel Arduino RVB.

/* 
 * Contrôler une LED RVB avec une télécommande TV
 * 
 * Exemple IRrecvDemo modifié de la bibliothèque IRremote de Ken Shirriff
 * Ken Shirriff
 * https://arcfn.com
 * 
 * Modifié par Dejan Nedelkovski,
 * www.HowToMechatronics.com
 */
#include <IRremote.h>

int RECV_PIN = 8; // Récepteur IR - Broche Arduino numéro 8
IRrecv irrecv(RECV_PIN);
decode_results results;

int redPin = 5;
int greenPin = 6;
int bluePin = 7;

void setup() {
  Serial.begin(9600);
  irrecv.enableIRIn(); // Démarre le récepteur
  pinMode(redPin, OUTPUT);
  pinMode(greenPin, OUTPUT);
  pinMode(bluePin, OUTPUT);
}

void loop() {
  if (irrecv.decode(&results)) {
    if (results.value == 0xF21D7D46) { // Bouton Rouge
      setColor(255, 0, 0); // Définit la couleur rouge sur la LED RVB
      delay(100);
    }
    if (results.value == 0x87CF1B29) { // Bouton Vert
      setColor(0, 255, 0); // Couleur verte
      delay(100);
    }
    if (results.value == 0x6623D37C) { // Bouton Jaune
      setColor(255, 255, 0); // Couleur jaune
      delay(100);
    }
    if (results.value == 0x854115F2) { // Bouton Bleu
      setColor(0, 0, 255); // Couleur bleue
      delay(100);
    }
    if (results.value == 0x1639AB6E) { // Bouton Stop
      setColor(0, 0, 0); // ÉTEINT
      delay(100);
    }
    irrecv.resume(); // Recevoir la valeur suivante
  }
  delay(100);
}

// Fonction personnalisée pour activer la LED RVB
void setColor(int red, int green, int blue) {
  analogWrite(redPin, red); // Envoie signal PWM à la broche rouge
  analogWrite(greenPin, green);
  analogWrite(bluePin, blue);
}

Voici le schéma de câblage de la LED RVB contrôlée par IR Arduino :

Contrôler la vitesse d'un ventilateur DC avec une télécommande TV

---

Composants nécessaires pour cet exemple :

• Moteur DC
• ou Ventilateur DC
• Transistor NPN
• Diode
• Condensateur – 1uF
• Résistance – 1k Ohms

Dans cet exemple, nous contrôlerons la vitesse d'un ventilateur DC en utilisant les boutons avant et arrière de la télécommande TV. Nous utiliserons ce schéma de câblage pour contrôler la vitesse du ventilateur, ou en fait nous contrôlerons le signal PWM en utilisant les boutons. Pour plus de détails sur le fonctionnement de ce schéma de câblage, vous pouvez consulter mon tutoriel Arduino Moteurs.

Voici le code source pour cet exemple. En utilisant la fonction analogWrite(), nous enverrons un signal PWM à la base du transistor. Le bouton PLAY démarrera le moteur à vitesse maximale, ou le cycle de travail du signal PWM sera à 100 % et le bouton STOP l'arrêtera. Le bouton avant augmentera la vitesse du ventilateur à chaque pression en augmentant le cycle de travail du signal PWM, et le bouton arrière le diminuera.

/* 
 * Contrôler la vitesse d'un ventilateur DC avec une télécommande TV
 * 
 * Exemple IRrecvDemo modifié de la bibliothèque IRremote de Ken Shirriff
 * Ken Shirriff
 * https://arcfn.com
 * 
 * Modifié par Dejan Nedelkovski,
 * www.HowToMechatronics.com
 */
#include <IRremote.h>

int RECV_PIN = 8; // Récepteur IR - Broche Arduino numéro 8
int pwmPin = 7; // Broche Arduino numéro 7 vers la base du transistor
int pwmValue;

IRrecv irrecv(RECV_PIN);
decode_results results;

void setup() {
  Serial.begin(9600);
  irrecv.enableIRIn(); // Démarre le récepteur
  pinMode(pwmPin, OUTPUT);
  pwmValue = 0; // Démarre le programme avec le moteur éteint
}

void loop() {
  if (irrecv.decode(&results)) {
    analogWrite(pwmPin, pwmValue);
    if (results.value == 0xAFAF8374) { // Bouton PLAY
      pwmValue = 255; // Cycle de travail 100% | Vitesse max
    }
    if (results.value == 0x98519C65) { // Bouton STOP
      pwmValue = 0; // Cycle de travail 0% | Éteint
    }
    if (results.value == 0x93F1BA08) { // Bouton AVANT
      if(pwmValue <= 245){
        pwmValue = pwmValue + 10; // Augmente le cycle de travail du signal PWM
        delay(20);
      }
    }
    if (results.value == 0x71D086FF) { // Bouton ARRIÈRE
      if(pwmValue >= 20){
        pwmValue = pwmValue - 10; // Diminue le cycle de travail du signal PWM
        delay(20);
      }
    }
    Serial.print(pwmValue);
    Serial.print(" ");
    Serial.println(results.value, HEX);
    irrecv.resume(); // Recevoir la valeur suivante
  }
  delay(100);
}

Contrôler des appareils électroménagers haute tension avec une télécommande TV

---

Composants nécessaires pour ce tutoriel :

• Module relais 5V
• Câble, prise, douille

L'exemple final sera le contrôle d'appareils électroménagers haute tension en utilisant la télécommande TV. Pour cela, nous aurons besoin d'un module relais. J'utiliserai le module relais HL-52S qui a une puissance de 10 A à 250 et 125 V AC. Voici le schéma de câblage de l'exemple Arduino IR contrôle appareils haute tension. Avec la broche numéro 7 de la carte Arduino, nous contrôlerons le relais sur lequel il y a une douille pour connecter n'importe quel dispositif électronique haute tension.

Comme nous allons utiliser de la HAUTE TENSION, nous devons être très prudents et je vous avertis ici qu'une utilisation incorrecte ou inappropriée pourrait entraîner des blessures graves ou la mort et je ne prends aucune responsabilité pour vos actions. Pour plus de détails sur l'utilisation du relais et comment faire une douille pour brancher n'importe quel dispositif électronique, vous pouvez consulter mon tutoriel Arduino Relais.

Voici le code source de cet exemple :

/* 
 * Contrôler des appareils électroménagers haute tension avec une télécommande TV
 * 
 * Exemple IRrecvDemo modifié de la bibliothèque IRremote de Ken Shirriff
 * Ken Shirriff
 * https://arcfn.com
 * 
 * Modifié par Dejan,
 * www.HowToMechatronics.com
 */
#include <IRremote.h>

int RECV_PIN = 8;
int relayOut = 7;
int buttonState;
IRrecv irrecv(RECV_PIN);
decode_results results;

void setup() {
  Serial.begin(9600);
  irrecv.enableIRIn(); // Démarre le récepteur
  pinMode(relayOut, OUTPUT);
  buttonState = HIGH; // Démarre le programme avec le relais éteint. L'entrée du relais fonctionne inversement donc l'état HIGH signifie relais désactivé
}

void loop() {
  buttonState = digitalRead(relayOut);
  if (irrecv.decode(&results)) {
    if (results.value == 0xAFAF8374) { // Bouton PLAY
      digitalWrite(relayOut, LOW); // Active le relais
    }
    if (results.value == 0x98519C65) { // Bouton STOP
      digitalWrite(relayOut, HIGH); // Désactive le relais
    }
    irrecv.resume(); // Recevoir la valeur suivante
  }
  Serial.print(" ");
  Serial.println(results.value, HEX);
  delay(100);
}