Créer un éclairage de marquee LED dynamique avec Arduino Nano et NeoPixels

Bibliothèques

Le sketch nécessite une bibliothèque :

• Bibliothèque Adafruit NeoPixel

Licence

Des parties du sketch ont été trouvées sur internet, tout le crédit revient aux créateurs. Libre d'utilisation pour usage personnel, pas pour des fins commerciales. Vous pouvez me contacter à ericBcreator@gmail.com.

Code

Code d'éclairage de marquee animé

/* **********************************************************************
 * Éclairage de marquee avec NeoPixels par ericBcreator
 * script simple pour éclairer une marquee (d'arcade)
 **********************************************************************
 * dernière mise à jour 20181021 par ericBcreator
 *
 * Inspiré par un article de sandyjmacdonald
 * https://sandyjmacdonald.github.io/2015/12/02/picade-errata/
 *
 * composants :
 * - Bandeau NeoPixel
 * - Arduino Nano
 *
 * Ce code est libre pour usage personnel, pas pour des fins commerciales.
 * Merci de laisser cet en-tête intact.
 *
 * contact : ericBcreator@gmail.com
 ********************************************************************** */

// inclusion des bibliothèques
#include <Adafruit_NeoPixel.h>
#define PIN 2 // broche de connexion du bandeau

// variables de configuration et initialisation du bandeau NeoPixel
int numOfLeds = 11;          // nombre de LEDs sur le bandeau
int minBrightness = 80;      // luminosité minimum pour pulsation/clignotement (0-255)
int maxBrightness = 255;     // luminosité maximum pour pulsation/clignotement (0-255)
int walkingLedsDelay = 250;  // délai en ms pour les LEDs qui « marchent »
int flashDelay = 250;        // délai en ms pour le clignotement
int numOfFlashLoops = 3;     // nombre de boucles de clignotement
int numOfPulseLoops = 10;    // nombre de boucles de pulsation min/max
int pulseDelay = 20;         // délai en ms lors de la pulsation

Adafruit_NeoPixel strip = Adafruit_NeoPixel(numOfLeds, PIN);

void setup() {
  strip.begin();
}

void loop() {
  walkingLeds();  // affiche les LEDs qui marchent
  flashLeds();    // fait clignoter les LEDs
  for (int i = 0; i < numOfPulseLoops; i++) // pulse les LEDs
    pulseBrightness();
}

void walkingLeds() {
  setLedColorsToZero();
  strip.setBrightness(maxBrightness);
  strip.show();
  for (int x = numOfLeds; x > 0; x--) {
    strip.setPixelColor(x, strip.Color(255, 255, 255));
    strip.show();
    delay(walkingLedsDelay);
    strip.setPixelColor(x, 0);
    strip.show();
  }
}

void flashLeds() {
  setLedColors();
  for (int i = 0; i < numOfFlashLoops; i++) {
    strip.setBrightness(maxBrightness);
    strip.show();
    delay(flashDelay);
    strip.setBrightness(minBrightness);
    strip.show();
    delay(flashDelay);
  }
}

void pulseBrightness() {
  setLedColors();
  for (int i = minBrightness; i < maxBrightness; i++) {
    strip.setBrightness(i);
    strip.show();
    delay(pulseDelay);
  }
  for (int i = maxBrightness; i > minBrightness; i--) {
    strip.setBrightness(i);
    strip.show();
    delay(pulseDelay);
  }
}

void setLedColors() {
  for (int x = 0; x < numOfLeds; x++)
    strip.setPixelColor(x, strip.Color(255, 255, 255));
}

void setLedColorsToZero() {
  for (int x = 0; x < numOfLeds; x++)
    strip.setPixelColor(x, strip.Color(0, 0, 0));
}

Schéma